Instructions
Unlike previous notebooks we’ve used for activities, this notebook does not define any new functions.

Instead, there are three examples: one which helps to check the simple surface condition; one which plots a simple surface; and another which plots a surface with curves on it, both using built-in functions.

Example 1
Remember that the regularity condition for surfaces demands that the cross product (Subscript[F, u])× (Subscript[F, v])be nonzero, for all input values (u,v).  Here (Subscript[F, u]) and (Subscript[F, v]) are the columns of dF.  The following cell computes this cross product.

surfaceF[u_,v_]:={Cos[u],Sin[u],v};
Simplify[Cross[D[surfaceF[uu,v],uu],D[surfaceF[u,vv],vv]]/.uu->u/.vv->v]

In order to know that we have a simple surface, we need this cross product to never vanish.  We can verify this by computing the vector’s magnitude:

Simplify[Norm[Cross[D[surfaceF[uu,v],uu],D[surfaceF[u,vv],vv]]/.uu->u/.vv->v]]

Since this simplifies to the constant value 1, the surface defined above is regular.

Example 2
We can plot simple surfaces in 3D using the built-in function ParametricPlot3D.  The following cell plots the surface F(u,v)=(cos(u),sin(u),v), with domain 0≤u≤2π, -2≤v≤2.  Hopefully you can convince yourself that this gives a right circular cylinder of radius 1 (and with height 4).

ParametricPlot3D[{Cos[u],Sin[u],v},{u,0,2Pi},{v,-2,2}]

We can also have some fun with the radius of our cylinder.  In the following example, the radius will vary with v (which controls the z-coordinate on our surface).

ParametricPlot3D[{(1+0.2*Cos[5v])Cos[u],(1+0.2*Cos[5v])Sin[u],v},{u,0,2Pi},{v,-2,2}]

Example 3
Our final example will really be a continuation of the previous one.  Now we want to add curves on the surface.

Mathematically, this will mean choosing a curve in the domain (i.e., the u v-plane) and then just plugging into the surface parametrization.  For instance, we can get a curve on the cylinder above by holding u constant and allowing v to vary.  This will just give a vertical line.

To make Mathematica plot this, we’ll combine instances of ParametricPlot3D using Show.

Show[
ParametricPlot3D[{Cos[u],Sin[u],v},{u,0,2Pi},{v,-2,2}],(*just the surface from before*)
ParametricPlot3D[{Cos[3Pi/2],Sin[3Pi/2],v},{v,-2,2},PlotStyle->{{Green,Thickness[0.02]}}](*same thing, but we replaced u with 3Pi/2, and removed its ability to vary*)
](*we also added PlotStyle which you can edit as you wish, or just ignore.  there's documentation online.*)

Here’s a cute upgrade on the vase we built in Example 2.  Trying to figure out what each curve is doing in this example might help you get started on one of the problems on Activity 5.

Show[
ParametricPlot3D[{(1+0.2*Cos[5v])Cos[u],(1+0.2*Cos[5v])Sin[u],v},{u,0,2Pi},{v,-2,2}],
ParametricPlot3D[{(1+0.2*Cos[5v])Cos[0],(1+0.2*Cos[5v])Sin[0],v},{v,-2,2},PlotStyle->{{Red,Thickness[0.02]}}],ParametricPlot3D[{(1+0.2*Cos[5v])Cos[Pi],(1+0.2*Cos[5v])Sin[Pi],v},{v,-2,2},PlotStyle->{{Green,Thickness[0.02]}}],
ParametricPlot3D[{(1+0.2*Cos[5(-((2Pi)/5))])Cos[u],(1+0.2*Cos[5(-((2Pi)/5))])Sin[u],-((2Pi)/5)},{u,0,2Pi},PlotStyle->{{Blue,Thickness[0.02]}}],ParametricPlot3D[{(1+0.2*Cos[5(u/3)])Cos[u],(1+0.2*Cos[5(u/3)])Sin[u],(u/3)},{u,-2Pi,2Pi},PlotStyle->{{Black,Thickness[0.02]}}](*this last one is wild. can you see what's going on?*)
]

Your code
Type your code below (or just copy the code from above and substitute as needed).
Remember that you can compile a code cell using ‘Shift+Enter’.
Warning: Don’t type code directly into this cell, as it only accepts text.  Type your code in a new cell below.